<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package TAP::Parser::Grammar;

use strict;
use warnings;

use TAP::Parser::ResultFactory   ();
use TAP::Parser::YAMLish::Reader ();

use base 'TAP::Object';

=head1 NAME

TAP::Parser::Grammar - A grammar for the Test Anything Protocol.

=head1 VERSION

Version 3.43

=cut

our $VERSION = '3.43';

=head1 SYNOPSIS

  use TAP::Parser::Grammar;
  my $grammar = $self-&gt;make_grammar({
    iterator =&gt; $tap_parser_iterator,
    parser   =&gt; $tap_parser,
    version  =&gt; 12,
  });

  my $result = $grammar-&gt;tokenize;

=head1 DESCRIPTION

C&lt;TAP::Parser::Grammar&gt; tokenizes lines from a L&lt;TAP::Parser::Iterator&gt; and
constructs L&lt;TAP::Parser::Result&gt; subclasses to represent the tokens.

Do not attempt to use this class directly.  It won't make sense.  It's mainly
here to ensure that we will be able to have pluggable grammars when TAP is
expanded at some future date (plus, this stuff was really cluttering the
parser).

=head1 METHODS

=head2 Class Methods

=head3 C&lt;new&gt;

  my $grammar = TAP::Parser::Grammar-&gt;new({
      iterator =&gt; $iterator,
      parser   =&gt; $parser,
      version  =&gt; $version,
  });

Returns L&lt;TAP::Parser&gt; grammar object that will parse the TAP stream from the
specified iterator.  Both C&lt;iterator&gt; and C&lt;parser&gt; are required arguments.
If C&lt;version&gt; is not set it defaults to C&lt;12&gt; (see L&lt;/set_version&gt; for more
details).

=cut

# new() implementation supplied by TAP::Object
sub _initialize {
    my ( $self, $args ) = @_;
    $self-&gt;{iterator} = $args-&gt;{iterator};    # TODO: accessor
    $self-&gt;{iterator} ||= $args-&gt;{stream};    # deprecated
    $self-&gt;{parser} = $args-&gt;{parser};        # TODO: accessor
    $self-&gt;set_version( $args-&gt;{version} || 12 );
    return $self;
}

my %language_for;

{

    # XXX the 'not' and 'ok' might be on separate lines in VMS ...
    my $ok  = qr/(?:not )?ok\b/;
    my $num = qr/\d+/;

    my %v12 = (
        version =&gt; {
            syntax  =&gt; qr/^TAP\s+version\s+(\d+)\s*\z/i,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my $version = $1;
                return $self-&gt;_make_version_token( $line, $version, );
            },
        },
        plan =&gt; {
            syntax  =&gt; qr/^1\.\.(\d+)\s*(.*)\z/,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my ( $tests_planned, $tail ) = ( $1, $2 );
                my $explanation = undef;
                my $skip        = '';

                if ( $tail =~ /^todo((?:\s+\d+)+)/ ) {
                    my @todo = split /\s+/, _trim($1);
                    return $self-&gt;_make_plan_token(
                        $line, $tests_planned, 'TODO',
                        '',    \@todo
                    );
                }
                elsif ( 0 == $tests_planned ) {
                    $skip = 'SKIP';

                    # If we can't match # SKIP the directive should be undef.
                    ($explanation) = $tail =~ /^#\s*SKIP\S*\s+(.*)/i;
                }
                elsif ( $tail !~ /^\s*$/ ) {
                    return $self-&gt;_make_unknown_token($line);
                }

                $explanation = '' unless defined $explanation;

                return $self-&gt;_make_plan_token(
                    $line, $tests_planned, $skip,
                    $explanation, []
                );

            },
        },

        # An optimization to handle the most common test lines without
        # directives.
        simple_test =&gt; {
            syntax  =&gt; qr/^($ok) \ ($num) (?:\ ([^#]+))? \z/x,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my ( $ok, $num, $desc ) = ( $1, $2, $3 );

                return $self-&gt;_make_test_token(
                    $line, $ok, $num,
                    $desc
                );
            },
        },
        test =&gt; {
            syntax  =&gt; qr/^($ok) \s* ($num)? \s* (.*) \z/x,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my ( $ok, $num, $desc ) = ( $1, $2, $3 );
                my ( $dir, $explanation ) = ( '', '' );
                if ($desc =~ m/^ ( [^\\\#]* (?: \\. [^\\\#]* )* )
                       \# \s* (SKIP|TODO) \b \s* (.*) $/ix
                  )
                {
                    ( $desc, $dir, $explanation ) = ( $1, $2, $3 );
                }
                return $self-&gt;_make_test_token(
                    $line, $ok, $num, $desc,
                    $dir,  $explanation
                );
            },
        },
        comment =&gt; {
            syntax  =&gt; qr/^#(.*)/,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my $comment = $1;
                return $self-&gt;_make_comment_token( $line, $comment );
            },
        },
        bailout =&gt; {
            syntax  =&gt; qr/^\s*Bail out!\s*(.*)/,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my $explanation = $1;
                return $self-&gt;_make_bailout_token(
                    $line,
                    $explanation
                );
            },
        },
    );

    my %v13 = (
        %v12,
        plan =&gt; {
            syntax  =&gt; qr/^1\.\.(\d+)\s*(?:\s*#\s*SKIP\b(.*))?\z/i,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my ( $tests_planned, $explanation ) = ( $1, $2 );
                my $skip
                  = ( 0 == $tests_planned || defined $explanation )
                  ? 'SKIP'
                  : '';
                $explanation = '' unless defined $explanation;
                return $self-&gt;_make_plan_token(
                    $line, $tests_planned, $skip,
                    $explanation, []
                );
            },
        },
        yaml =&gt; {
            syntax  =&gt; qr/^ (\s+) (---.*) $/x,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my ( $pad, $marker ) = ( $1, $2 );
                return $self-&gt;_make_yaml_token( $pad, $marker );
            },
        },
        pragma =&gt; {
            syntax =&gt;
              qr/^ pragma \s+ ( [-+] \w+ \s* (?: , \s* [-+] \w+ \s* )* ) $/x,
            handler =&gt; sub {
                my ( $self, $line ) = @_;
                my $pragmas = $1;
                return $self-&gt;_make_pragma_token( $line, $pragmas );
            },
        },
    );

    %language_for = (
        '12' =&gt; {
            tokens =&gt; \%v12,
        },
        '13' =&gt; {
            tokens =&gt; \%v13,
            setup  =&gt; sub {
                shift-&gt;{iterator}-&gt;handle_unicode;
            },
        },
    );
}

##############################################################################

=head2 Instance Methods

=head3 C&lt;set_version&gt;

  $grammar-&gt;set_version(13);

Tell the grammar which TAP syntax version to support. The lowest
supported version is 12. Although 'TAP version' isn't valid version 12
syntax it is accepted so that higher version numbers may be parsed.

=cut

sub set_version {
    my $self    = shift;
    my $version = shift;

    if ( my $language = $language_for{$version} ) {
        $self-&gt;{version} = $version;
        $self-&gt;{tokens}  = $language-&gt;{tokens};

        if ( my $setup = $language-&gt;{setup} ) {
            $self-&gt;$setup();
        }

        $self-&gt;_order_tokens;
    }
    else {
        require Carp;
        Carp::croak("Unsupported syntax version: $version");
    }
}

# Optimization to put the most frequent tokens first.
sub _order_tokens {
    my $self = shift;

    my %copy = %{ $self-&gt;{tokens} };
    my @ordered_tokens = grep {defined}
      map { delete $copy{$_} } qw( simple_test test comment plan );
    push @ordered_tokens, values %copy;

    $self-&gt;{ordered_tokens} = \@ordered_tokens;
}

##############################################################################

=head3 C&lt;tokenize&gt;

  my $token = $grammar-&gt;tokenize;

This method will return a L&lt;TAP::Parser::Result&gt; object representing the
current line of TAP.

=cut

sub tokenize {
    my $self = shift;

    my $line = $self-&gt;{iterator}-&gt;next;
    unless ( defined $line ) {
        delete $self-&gt;{parser};    # break circular ref
        return;
    }

    my $token;

    for my $token_data ( @{ $self-&gt;{ordered_tokens} } ) {
        if ( $line =~ $token_data-&gt;{syntax} ) {
            my $handler = $token_data-&gt;{handler};
            $token = $self-&gt;$handler($line);
            last;
        }
    }

    $token = $self-&gt;_make_unknown_token($line) unless $token;

    return $self-&gt;{parser}-&gt;make_result($token);
}

##############################################################################

=head3 C&lt;token_types&gt;

  my @types = $grammar-&gt;token_types;

Returns the different types of tokens which this grammar can parse.

=cut

sub token_types {
    my $self = shift;
    return keys %{ $self-&gt;{tokens} };
}

##############################################################################

=head3 C&lt;syntax_for&gt;

  my $syntax = $grammar-&gt;syntax_for($token_type);

Returns a pre-compiled regular expression which will match a chunk of TAP
corresponding to the token type.  For example (not that you should really pay
attention to this, C&lt;&lt; $grammar-&gt;syntax_for('comment') &gt;&gt; will return
C&lt;&lt; qr/^#(.*)/ &gt;&gt;.

=cut

sub syntax_for {
    my ( $self, $type ) = @_;
    return $self-&gt;{tokens}-&gt;{$type}-&gt;{syntax};
}

##############################################################################

=head3 C&lt;handler_for&gt;

  my $handler = $grammar-&gt;handler_for($token_type);

Returns a code reference which, when passed an appropriate line of TAP,
returns the lexed token corresponding to that line.  As a result, the basic
TAP parsing loop looks similar to the following:

 my @tokens;
 my $grammar = TAP::Grammar-&gt;new;
 LINE: while ( defined( my $line = $parser-&gt;_next_chunk_of_tap ) ) {
     for my $type ( $grammar-&gt;token_types ) {
         my $syntax  = $grammar-&gt;syntax_for($type);
         if ( $line =~ $syntax ) {
             my $handler = $grammar-&gt;handler_for($type);
             push @tokens =&gt; $grammar-&gt;$handler($line);
             next LINE;
         }
     }
     push @tokens =&gt; $grammar-&gt;_make_unknown_token($line);
 }

=cut

sub handler_for {
    my ( $self, $type ) = @_;
    return $self-&gt;{tokens}-&gt;{$type}-&gt;{handler};
}

sub _make_version_token {
    my ( $self, $line, $version ) = @_;
    return {
        type    =&gt; 'version',
        raw     =&gt; $line,
        version =&gt; $version,
    };
}

sub _make_plan_token {
    my ( $self, $line, $tests_planned, $directive, $explanation, $todo ) = @_;

    if (   $directive eq 'SKIP'
        &amp;&amp; 0 != $tests_planned
        &amp;&amp; $self-&gt;{version} &lt; 13 )
    {
        warn
          "Specified SKIP directive in plan but more than 0 tests ($line)\n";
    }

    return {
        type          =&gt; 'plan',
        raw           =&gt; $line,
        tests_planned =&gt; $tests_planned,
        directive     =&gt; $directive,
        explanation   =&gt; _trim($explanation),
        todo_list     =&gt; $todo,
    };
}

sub _make_test_token {
    my ( $self, $line, $ok, $num, $desc, $dir, $explanation ) = @_;
    return {
        ok          =&gt; $ok,

        # forcing this to be an integer (and not a string) reduces memory
        # consumption. RT #84939
        test_num    =&gt; ( defined $num ? 0 + $num : undef ),
        description =&gt; _trim($desc),
        directive   =&gt; ( defined $dir ? uc $dir : '' ),
        explanation =&gt; _trim($explanation),
        raw         =&gt; $line,
        type        =&gt; 'test',
    };
}

sub _make_unknown_token {
    my ( $self, $line ) = @_;
    return {
        raw  =&gt; $line,
        type =&gt; 'unknown',
    };
}

sub _make_comment_token {
    my ( $self, $line, $comment ) = @_;
    return {
        type    =&gt; 'comment',
        raw     =&gt; $line,
        comment =&gt; _trim($comment)
    };
}

sub _make_bailout_token {
    my ( $self, $line, $explanation ) = @_;
    return {
        type    =&gt; 'bailout',
        raw     =&gt; $line,
        bailout =&gt; _trim($explanation)
    };
}

sub _make_yaml_token {
    my ( $self, $pad, $marker ) = @_;

    my $yaml = TAP::Parser::YAMLish::Reader-&gt;new;

    my $iterator = $self-&gt;{iterator};

    # Construct a reader that reads from our input stripping leading
    # spaces from each line.
    my $leader = length($pad);
    my $strip  = qr{ ^ (\s{$leader}) (.*) $ }x;
    my @extra  = ($marker);
    my $reader = sub {
        return shift @extra if @extra;
        my $line = $iterator-&gt;next;
        return $2 if $line =~ $strip;
        return;
    };

    my $data = $yaml-&gt;read($reader);

    # Reconstitute input. This is convoluted. Maybe we should just
    # record it on the way in...
    chomp( my $raw = $yaml-&gt;get_raw );
    $raw =~ s/^/$pad/mg;

    return {
        type =&gt; 'yaml',
        raw  =&gt; $raw,
        data =&gt; $data
    };
}

sub _make_pragma_token {
    my ( $self, $line, $pragmas ) = @_;
    return {
        type    =&gt; 'pragma',
        raw     =&gt; $line,
        pragmas =&gt; [ split /\s*,\s*/, _trim($pragmas) ],
    };
}

sub _trim {
    my $data = shift;

    return '' unless defined $data;

    $data =~ s/^\s+//;
    $data =~ s/\s+$//;
    return $data;
}

1;

=head1 TAP GRAMMAR

B&lt;NOTE:&gt;  This grammar is slightly out of date.  There's still some discussion
about it and a new one will be provided when we have things better defined.

The L&lt;TAP::Parser&gt; does not use a formal grammar because TAP is essentially a
stream-based protocol.  In fact, it's quite legal to have an infinite stream.
For the same reason that we don't apply regexes to streams, we're not using a
formal grammar here.  Instead, we parse the TAP in lines.

For purposes for forward compatibility, any result which does not match the
following grammar is currently referred to as
L&lt;TAP::Parser::Result::Unknown&gt;.  It is I&lt;not&gt; a parse error.

A formal grammar would look similar to the following:

 (*
     For the time being, I'm cheating on the EBNF by allowing
     certain terms to be defined by POSIX character classes by
     using the following syntax:

       digit ::= [:digit:]

     As far as I am aware, that's not valid EBNF.  Sue me.  I
     didn't know how to write "char" otherwise (Unicode issues).
     Suggestions welcome.
 *)

 tap            ::= version? { comment | unknown } leading_plan lines
                    |
                    lines trailing_plan {comment}

 version        ::= 'TAP version ' positiveInteger {positiveInteger} "\n"

 leading_plan   ::= plan skip_directive? "\n"

 trailing_plan  ::= plan "\n"

 plan           ::= '1..' nonNegativeInteger

 lines          ::= line {line}

 line           ::= (comment | test | unknown | bailout ) "\n"

 test           ::= status positiveInteger? description? directive?

 status         ::= 'not '? 'ok '

 description    ::= (character - (digit | '#')) {character - '#'}

 directive      ::= todo_directive | skip_directive

 todo_directive ::= hash_mark 'TODO' ' ' {character}

 skip_directive ::= hash_mark 'SKIP' ' ' {character}

 comment        ::= hash_mark {character}

 hash_mark      ::= '#' {' '}

 bailout        ::= 'Bail out!' {character}

 unknown        ::= { (character - "\n") }

 (* POSIX character classes and other terminals *)

 digit              ::= [:digit:]
 character          ::= ([:print:] - "\n")
 positiveInteger    ::= ( digit - '0' ) {digit}
 nonNegativeInteger ::= digit {digit}

=head1 SUBCLASSING

Please see L&lt;TAP::Parser/SUBCLASSING&gt; for a subclassing overview.

If you I&lt;really&gt; want to subclass L&lt;TAP::Parser&gt;'s grammar the best thing to
do is read through the code.  There's no easy way of summarizing it here.

=head1 SEE ALSO

L&lt;TAP::Object&gt;,
L&lt;TAP::Parser&gt;,
L&lt;TAP::Parser::Iterator&gt;,
L&lt;TAP::Parser::Result&gt;,

=cut
</pre></body></html>