<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># $Id: Objects.pm,v 1.1 2003-08-18 20:20:51 matt Exp $

package XML::Parser::Style::Objects;
use strict;

sub Init {
    my $expat = shift;
    $expat-&gt;{Lists} = [];
    $expat-&gt;{Curlist} = $expat-&gt;{Tree} = [];
}

sub Start {
    my $expat   = shift;
    my $tag     = shift;
    my $newlist = [];
    my $class   = "${$expat}{Pkg}::$tag";
    my $newobj  = bless { @_, Kids =&gt; $newlist }, $class;
    push @{ $expat-&gt;{Lists} },   $expat-&gt;{Curlist};
    push @{ $expat-&gt;{Curlist} }, $newobj;
    $expat-&gt;{Curlist} = $newlist;
}

sub End {
    my $expat = shift;
    my $tag   = shift;
    $expat-&gt;{Curlist} = pop @{ $expat-&gt;{Lists} };
}

sub Char {
    my $expat = shift;
    my $text  = shift;
    my $class = "${$expat}{Pkg}::Characters";
    my $clist = $expat-&gt;{Curlist};
    my $pos   = $#$clist;

    if ( $pos &gt;= 0 and ref( $clist-&gt;[$pos] ) eq $class ) {
        $clist-&gt;[$pos]-&gt;{Text} .= $text;
    }
    else {
        push @$clist, bless { Text =&gt; $text }, $class;
    }
}

sub Final {
    my $expat = shift;
    delete $expat-&gt;{Curlist};
    delete $expat-&gt;{Lists};
    $expat-&gt;{Tree};
}

1;
__END__

=head1 NAME

XML::Parser::Style::Objects - Objects styler parser

=head1 SYNOPSIS

  use XML::Parser;
  my $p = XML::Parser-&gt;new(Style =&gt; 'Objects', Pkg =&gt; 'MyNode');
  my $tree = $p-&gt;parsefile('foo.xml');

=head1 DESCRIPTION

This module implements XML::Parser's Objects style parser.

This is similar to the Tree style, except that a hash object is created for
each element. The corresponding object will be in the class whose name
is created by appending "::" and the element name to the package set with
the Pkg option. Non-markup text will be in the ::Characters class. The
contents of the corresponding object will be in an anonymous array that
is the value of the Kids property for that object.

=head1 SEE ALSO

L&lt;XML::Parser::Style::Tree&gt;

=cut
</pre></body></html>