<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright Â© 2022 Guillem Jover &lt;guillem@debian.org&gt;
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

=encoding utf8

=head1 NAME

Dpkg::OpenPGP::KeyHandle - OpenPGP key handle support

=head1 DESCRIPTION

This module provides a class to hold an OpenPGP key handle, as a way for
the code to refer to a key in an independent way.

B&lt;Note&gt;: This is a private module, its API can change at any time.

=cut

package Dpkg::OpenPGP::KeyHandle 0.01;

use strict;
use warnings;

use Carp;
use List::Util qw(any none);

sub new {
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;

    my $self = {
        type =&gt; $opts{type} // 'auto',
        handle =&gt; $opts{handle},
    };
    bless $self, $class;

    $self-&gt;_sanitize();

    return $self;
}

my $keyid_regex = qr/^(?:0x)?([[:xdigit:]]+)$/;

sub _sanitize {
    my ($self) = shift;

    my $type = $self-&gt;{type};
    if ($type eq 'auto') {
        if (-e $self-&gt;{handle}) {
            $type = 'keyfile';
        } else {
            $type = 'autoid';
        }
    }

    if ($type eq 'autoid') {
        if ($self-&gt;{handle} =~ m/$keyid_regex/) {
            $self-&gt;{handle} = $1;
            $type = 'keyid';
        } else {
            $type = 'userid';
        }
        $self-&gt;{type} = $type;
    } elsif ($type eq 'keyid') {
        if ($self-&gt;{handle} =~ m/$keyid_regex/) {
            $self-&gt;{handle} = $1;
        }
    }

    if (none { $type eq $_ } qw(userid keyid keyfile keystore)) {
        croak "unknown type parameter value $type";
    }

    return;
}

sub needs_keystore {
    my $self = shift;

    return any { $self-&gt;{type} eq $_ } qw(keyid userid);
}

sub set {
    my ($self, $type, $handle) = @_;

    $self-&gt;{type} = $type;
    $self-&gt;{handle} = $handle;

    $self-&gt;_sanitize();
}

sub type {
    my $self = shift;

    return $self-&gt;{type};
}

sub handle {
    my $self = shift;

    return $self-&gt;{handle};
}

=head1 CHANGES

=head2 Version 0.xx

This is a private module.

=cut

1;
</pre></body></html>